[ASM 68000] Petit défi rotation de tile 32×32 90°

Bonjour,

Voici le code avec des commentaires. Si pas clair, n’hésitez pas afin que je corrige.

A+

*-----------------------------------------------------------
* Title :
* Written by :
* Date :
* Description:
*-----------------------------------------------------------
ORG $1000

START

Afficher equ 0

OffsetEntre2Rotations equ 32*4+4 'tile + offset

Tourner90Degres:
;sur lettre G
;249770 / 90134

;principe
;image source(x,y)

;image source 0° (x,y)
;l'image source est composée de 32 lignes de 32 bits
; ....F
; .....
; .....
; 678..
; 12345
;
;on lit l'image source 0° dans l'ordre défini par 1,2,3,..,F (pour Fin)
;on balaye x en partant du bit 31 pour arriver au bit 0
;puis on change de ligne Y en remontant (on va de 31 à 0)

;image DEST 90° (X90, Y90)=(31-y, x)
; F...5
; ....4
; ...83
; ...72
; ...61
;
; le pixel X90 est défini par d5 qui s'incrémente à chaque fois qu'on change de ligne source y
; le pixel Y90 est defini par l'adresse (a5) qui se décrémente à chaque fois que x se décrémente

;image DEST 180° (X180, Y180)=(31-x,31-y)
; 54321
; .....
; .....
; .....
; F....
;
; le pixel X180 est défini par d4 qui s'icrémente à chaque fois que x se décrémente
; le pixel Y180 est defini par l'adresse (a2) qui s'incrémente à chaque fois que y se décrémente

;image DEST 270° (X270, Y270)=(y, 31-x)
; 1....
; 2....
; 3....
; 4....
; 5...F
;
; le pixel X270 est défini par d7 qui se décrémente à chaque fois que y se décrémente
; le pixel Y270 est defini l'as=dresse (a6) qui s'incrémente à chaque fois que x se décrémente

;-- on charge les adresses des Tiles 32x32
lea ImageSource+32*4(pc),a0 ;0° tile d'origine, on se place sur la dernière ligne
lea ImageSource+(1*OffsetEntre2Rotations)+(31*4)(pc),a1 ;adresse image destination 90°, on se place à la fin
lea ImageSource+2*OffsetEntre2Rotations(pc),a2 ;180°
lea ImageSource+(3*OffsetEntre2Rotations)(pc),a3 ;270°

moveq.l #0,d5 ;31-y -> [0..31]
moveq.l #31,d7 ;y -> [31..0]

.loopY:
;d7 indique la position Y de la ligne lue

move.l -(a0),d0 ;données source
;-(a0) permet de faire a0=a0-4 octets donc on remonte d'une ligne source
;d0 recoit alors les 32 bits de la ligne source indiquée par a0
;rappel : on commence par la dernière puisque a0 est l'adresse de fin

move.l a1,a5 ;on copie l'adresse du tile de destination 90° dans a5
move.l a3,a6 ;idem pour le tile 270
moveq.l #0,d1 ;on met tout à zero pour la ligne 180°

moveq.l #31,d6 ;x --> [31..0]
moveq.l #0,d4 ;31-x --> [0..31]
.loopX:

;le bit 31 (poids fort) est à gauche, et le bit 0 à droite (poids faible)
btst d6,d0 ;on teste le bit x (d6) de la ligne y (valeur dans d0)
beq .FinTraitement ; si à 0 (pixel éteint) on saute

;Pixel à 1, on traite

;--rot 90° sens trigo soit activer le pixel (31-y,x)
move.l (a5),d3 ;on charge la ligne dans d3
bset.l d5,d3 ;on met à 1 le bit 31-y (valeur d5) de d3
move.l d3,(a5) ;on sauve la valeur de d3 à l'adresse a5

;--rot 180° sens trigo soit (31-x,31-y)
bset.l d4,d1 ;on met à 1 le bit 31-x

;--rot 270° sens trigo soit (y,31-x)
move.l (a6),d3
bset.l d7,d3 ;y
move.l d3,(a6)

.FinTraitement:
sub.l #4,a5 ;90°, on remonte d'une ligne en fonction de x
add.l #4,a6 ;270°, on descend d'une ligne en fonction de x

addq.b #1,d4 ;31-y
dbra d6,.loopX ;x=x-1, et on boucle tant que x>=0

;fin de colonne x
move.l d1,(a2)+ ;data 180° : on sauve la ligne

addq.b #1,d5 ;31-y
dbra d7,.loopY ;y=y-1, et on boucle tant que y>=0

IFNE Afficher
jsr Afficher4Tiles
ENDC

rts

Afficher4Tiles:
;affiche image origine
lea ImageSource(pc),a0
move.l #0,d5
bsr afficherGFX

;affiche image 90°
lea ImageSource(pc),a0
add.l #OffsetEntre2Rotations, a0
move.l #64,d5
bsr afficherGFX

;affiche image 180
lea ImageSource(pc),a0
add.l #2*OffsetEntre2Rotations, a0
move.l #128,d5
bsr afficherGFX

;affiche image 270
lea ImageSource(pc),a0
add.l #3*OffsetEntre2Rotations, a0
move.l #192,d5
bsr afficherGFX

rts

afficherGFX:
;a0 = adr de départ
;d5 = offset y

add.l #32*4,a0
moveq.l #31,d7
.loopY:
;d7=Y compteur de lignes
move.l -(a0),d3
moveq.l #31,d6
;d6=X compteur de colonnes
.loopX:
btst d6,d3
beq .FinTraitement

;Pixel ON, on affiche
move.l #32,d1
sub.w d6,d1
move.w d7,d2
add.w d5,d2
MOVEQ #82,d0 * draw pixel d0=82, d1=x, d2=y
TRAP #15 * do draw

.FinTraitement:

dbra d6,.loopX
dbra d7,.loopY

rts

ImageSource:
dc.l %00000000000011111111000000000000
dc.l %00000000011111111111111000000000
dc.l %00000001111111111111111110000000
dc.l %00000011111111111111111111000000
dc.l %00000111111111111111111111100000
dc.l %00001111111111111111111111110000
dc.l %00011111111111111111111111111000
dc.l %00101111111110000000011111110100
dc.l %00101111111100000000001111100100
dc.l %01001111111100000000000000000010
dc.l %01001111111100000000000000000010
dc.l %01001111111100000000000000000010
dc.l %10001111111100000000000000000001
dc.l %10001111111100000000000000000001
dc.l %10001111111100000000000000000001
dc.l %10001111111100001111111111110001
dc.l %10001111111100001111111111110001
dc.l %10001111111100001111111111110001
dc.l %10001111111100001111111111110001
dc.l %10001111111100001111111111110001
dc.l %01001111111100000000011111110010
dc.l %01001111111100000000011111110010
dc.l %01001111111100000000011111110010
dc.l %00101111111100000000011111110100
dc.l %00101111111110000000011111110100
dc.l %00011111111111111111111111111000
dc.l %00001111111111111111111111110000
dc.l %00000111111111111111111111100000
dc.l %00000011111111111111111111000000
dc.l %00000001111111111111111110000000
dc.l %00000000011111111111111000000000
dc.l %00000000000011111111000000000000

dc.l $FFFF ;données arbitraires entre 2 tiles

ImageDest:
;TILE 90°
dc.l 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
dc.l $FFFF ;données arbitraires entre 2 tiles
;TILE 180°
dc.l 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
dc.l $FFFF ;données arbitraires entre 2 tiles
;TILE 270°
dc.l 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
dc.l $FFFF ;données arbitraires entre 2 tiles

;ds.l 32 ; remplit des 1 !!!

* Put program code here

SIMHALT ; halt simulator

* Put variables and constants here

END START ; last line of source

*~Font name~Courier New~
*~Font size~10~
*~Tab type~1~
*~Tab size~4~